DeltaVee program for graphing calculator

[AbacusWizard]

The other day I finally got tired of looking up I_sp values and typing "__*9.8*ln( __ / ( __ - 5*( __ + __ ) )" over and over again, so I decided to write a program for my graphing calculator to do it for me. The entire program is in the code block below; it should work on any TI-82/83/84 calculator. You can type it in manually or use TI Connect software (and a mini-USB cable) to transfer it directly. Let me know what you think.

 

 

Menu("FUEL TYPE?","LF/OX",L,"MONOPROP",P,"SOLID",S,"XENON",X)

Lbl L
1→F
Menu("LF/OX ENG. SIZE?","RADIAL",R,"0.625 M",R0,"1.250 M",R1,"2.500 M",R2,"3.125 M",R3

Lbl R
Menu("RADIAL ENGINE?","LV-1R SPIDER",2S,"24-77 TWITCH",2S,"MK-55 THUD",3B)

Lbl R0
Menu("0.625M ENGINE?","LV-1 ANT",3D,"48-7S SPARK",3A)

Lbl R1
Menu("1.250M ENGINE?","LV-909 TERRIER",3J,"T-1 AEROSPIKE",3I,"LV-T30 RELIANT",3A,"LV-T45 SWIVEL",3E,"CR-7 RAPIER",3B,"LV-N NERV ATOMIC",8A)

Lbl R2
Menu("2.500M ENGINE?","POODLE",3K,"SKIPPER",3E,"MAINSAIL",3C,"KR-1X2 TW.BOAR",3A)

Lbl R3
Menu("3.125M ENGINE?","KR-2L+ RHINO",3I,"KS-25X4 MAMOTH",3D)

Lbl P
2→F
Menu("MONOPR. ENGINE?","RCS THRUSTERS",2I,"O-10 PUFF",2K)

Lbl S
3→F
Menu("BOOSTER ROCKET?","SEPRATRON",1L,"RT-5 FLEA",1N,"RT-10 HAMMER",1T,"BACC THUMPER",2B,"KD25K KICKBACK",2D)

Lbl X
4→F
Menu("ION ENGINE?","IX-6315 DAWN",42)

Lbl 1L
154→I
Goto 0
Lbl 1N
165→I
Goto 0
Lbl 1T
195→I
Goto 0
Lbl 2B
210→I
Goto 0
Lbl 2D
220→I
Goto 0
Lbl 2I
240→I
Goto 0
Lbl 2K
250→I
Goto 0
Lbl 2S
290→I
Goto 0
Lbl 3A
300→I
Goto 0
Lbl 3B
305→I
Goto 0
Lbl 3C
310→I
Goto 0
Lbl 3D
315→I
Goto 0
Lbl 3E
320→I
Goto 0
Lbl 3I
340→I
Goto 0
Lbl 3J
345→I
Goto 0
Lbl 3K
350→I
Goto 0
Lbl 8A
800→I
Goto 0
Lbl 42
4200→I
Goto 0

Lbl 0
0→L
0→O
0→P
0→S
0→X
ClrHome
Input "CURRENT MASS?   ",M
M*1000→M
Disp ""
If F=1
Then
Input "LIQUID FUEL?    ",L
Disp ""
If I≠800
Input "OXIDIZER?       ",O
End
If F=2
Input "MONOPROP.?      ",P
If F=3
Input "SOLID FUEL?     ",S
If F=4
Input "XENON?          ",X
I*9.8*ln(M/(M-5*(L+O)-4*P-7.5*S-0.1*X))→V
ClrHome

Disp "","","DELTA V:",iPart(V),"             M/S",""
Pause 
Goto 0

 

When the calculator runs the program, it should display a menu asking what type of fuel you're using, then submenus asking which engine your ship has. After selecting an engine, you will be asked for the current mass of your ship (in tonnes) and the quantity of each relevant type of fuel. It should then output your ship's total ∆v available. It includes all the stock engines and adding more should be pretty easy.

(Moderators: I figured this seemed the most reasonable place to put this thread; feel free to move it elsewhere if that would make more sense.)

Edited January 22, 2016 by AbacusWizard

[Gargamel]

Very cool. I have since lost my ti-85 *tears*, but that would be very cool.

I don't think it would be a big step for you to produce this as a mod..... Yes MJ, KER, and other's do this for you already, but obviously there are purists that enjoy slide-rule-esque orbital mechanics, this would be the start of a cool mod.

[AbacusWizard]

I'm afraid it wouldn't work as is on a TI-85 (which uses a slightly different programming language than the 82/83/84 line), but it could probably be easily ported.

[klesh]

I see you looking at this old thread Darth Badie.  Please put a DeltaV calculator in the game.